8ピンSTM32で温湿度表示に挑戦！AQM1602＋DHT20を3ステップで動かす方法

#include <Wire.h>

#define AQM_ADDR 0x3E

void cmd(uint8_t c){
  Wire.beginTransmission(AQM_ADDR);
  Wire.write(0x00);
  Wire.write(c);
  Wire.endTransmission();
}

void data(uint8_t d){
  Wire.beginTransmission(AQM_ADDR);
  Wire.write(0x40);
  Wire.write(d);
  Wire.endTransmission();
}

void init_lcd(){
  delay(40);
  cmd(0x38);
  cmd(0x39);
  cmd(0x14);
  cmd(0x70);
  cmd(0x56);
  cmd(0x6C);
  delay(200);
  cmd(0x38);
  cmd(0x0C);
  cmd(0x01);
  delay(2);
}

void print_str(const char *s){
  while(*s) data(*s++);
}

void setup(){
  Wire.setSCL(PB6);
  Wire.setSDA(PB7);
  Wire.begin();
  init_lcd();
  print_str("Hello STM32");
}

void loop(){}

#include <Wire.h>

#define DHT20_ADDR 0x38

void setup(){　　　　//こちらの部分はAQM1602と共通のセットアップ項目です
  Wire.setSCL(PB6);
  Wire.setSDA(PB7);
  Wire.begin();
}

void loop(){
  Wire.beginTransmission(DHT20_ADDR);
  Wire.write(0xAC);
  Wire.write(0x33);
  Wire.write(0x00);
  Wire.endTransmission();
  delay(80);
}

#include <Wire.h>

#define AQM_ADDR 0x3E
#define DHT20_ADDR 0x38

//--------------------------------
// AQM1602 基本関数
//--------------------------------
void aqm_cmd(uint8_t cmd)
{
  Wire.beginTransmission(AQM_ADDR);
  Wire.write(0x00);
  Wire.write(cmd);
  Wire.endTransmission();
}

void aqm_data(uint8_t data)
{
  Wire.beginTransmission(AQM_ADDR);
  Wire.write(0x40);
  Wire.write(data);
  Wire.endTransmission();
}

void aqm_init()
{
  delay(40);
uint8_t initComs[] = {0x38, 0x39, 0x14, 0x70, 0x56, 0x6C, 0x38, 0x0C, 0x01};  //初期化コマンドを配列にまとめる場合
  uint16_t delays[]  = {2, 2, 2, 2, 2, 150, 2, 2, 2};
  for (uint8_t i = 0; i < sizeof(initComs); i++) {
       aqm_cmd(initComs[i]);
       delay(delays[i]);
  } 
}

void aqm_setCursor(uint8_t col, uint8_t row)
{
  uint8_t addr = (row == 0) ? 0x00 : 0x40;
  aqm_cmd(0x80 | (addr + col));
}

void aqm_print(const char *str)
{
  while (*str) {
    aqm_data(*str++);
  }
}

//--------------------------------
// DHT20 読み取り
//--------------------------------
bool dht20_read(float &temp, float &hum)
{
  uint8_t buf[7];

  // 測定開始
  Wire.beginTransmission(DHT20_ADDR);
  Wire.write(0xAC);
  Wire.write(0x33);
  Wire.write(0x00);
  if (Wire.endTransmission() != 0) return false;

  delay(80);

  // データ取得
  Wire.requestFrom(DHT20_ADDR, 7);
  for (int i = 0; i < 7; i++) {
    if (Wire.available()) buf[i] = Wire.read();
    else return false;
  }

  // 生データ変換
  uint32_t h_raw =
      ((uint32_t)buf[1] << 12) |
      ((uint32_t)buf[2] << 4)  |
      (buf[3] >> 4);

  uint32_t t_raw =
      ((uint32_t)(buf[3] & 0x0F) << 16) |
      ((uint32_t)buf[4] << 8) |
      buf[5];

  hum  = (h_raw * 100.0f) / 1048576.0f;
  temp = (t_raw * 200.0f) / 1048576.0f - 50.0f;

  return true;
}

//--------------------------------
// 数値を簡単表示（軽量版）
//--------------------------------
void print_float(float v)
{
  char buf[8];
  int i = (int)v;
  int d = (int)((v - i) * 10);

  if (d < 0) d = -d;

  snprintf(buf, sizeof(buf), "%d.%d", i, d);
  aqm_print(buf);
}

//--------------------------------
// setup
//--------------------------------
void setup()
{
  Wire.setSCL(PB6);
  Wire.setSDA(PB7);
  Wire.begin();
  Wire.setClock(100000);

  aqm_init();

  aqm_setCursor(0,0);
  aqm_print("STM32 + DHT20");
}

//--------------------------------
// loop
//--------------------------------
void loop()
{
  float t, h;

  if (dht20_read(t, h)) {

    aqm_setCursor(0,1);

    aqm_print("T:");
    print_float(t);

    aqm_print(" H:");
    print_float(h);
  }

  delay(2000);
}